soundboard/soundboard.pro

QT       += core gui multimedia

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17
CONFIG += debug_info
CONFIG += force_debug_info
unix:LIBS += -lX11 -ldl

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

SOURCES += \
    src/buttonsearch.cpp \
    src/main.cpp \
    src/mainwindow.cpp \
    src/sound.cpp \
    src/sounddevice.cpp \
    src/soundbutton.cpp \
    src/config.cpp \
    src/configdialog.cpp \
    src/editbutton.cpp \
    src/editsample.cpp \
    src/soundview.cpp \
    src/samplereader.cpp \
    src/settings.cpp \
    src/buttonmanager.cpp \
    src/buttonmanageritems.cpp \
    src/addnewwhat.cpp \
    src/keysequencevalidator.cpp \
    Log/Log.cpp

HEADERS += \
    include/buttonsearch.h \
    include/mainwindow.h \
    include/sound.h \
    include/sounddevice.h \
    include/soundbutton.h \
    include/config.h \
    include/configdialog.h \
    include/editbutton.h \
    include/editsample.h \
    include/soundview.h \
    include/samplereader.h \
    include/settings.h \
    include/buttonmanager.h \
    include/buttonmanageritems.h \
    include/addnewwhat.h \
    include/keysequencevalidator.h \
    miniaudio/miniaudio.h \
    Log/Log.h

MOC_DIR = generated/
UI_DIR = ui/
OBJECTS_DIR = obj/

FORMS += \
    ui/addnewwhat.ui \
    ui/buttonmanager.ui \
    ui/buttonsearch.ui \
    ui/editbutton.ui \
    ui/editsample.ui \
    ui/mainwindow.ui \
    ui/settings.ui

TRANSLATIONS += \
    testqt_de_DE.ts

INCLUDEPATH += $$PWD/include/ \
    $$PWD/miniaudio/ \
    $$PWD/Log/


# build AppImage
unix {
    $$PWD/linuxdeploy-x86_64.AppImage.commands = wget https://github.com/linuxdeploy/linuxdeploy/releases/download/continuous/linuxdeploy-x86_64.AppImage && chmod u+x linuxdeploy-x86_64.AppImage
    $$MOC_DIR/soundboard.svg.commands = touch $$MOC_DIR/soundboard.svg

    appimg.depends = $$PWD/linuxdeploy-x86_64.AppImage $${TARGET} $$MOC_DIR/soundboard.svg
    appimg.commands = rm -rf AppDir ; ./linuxdeploy-x86_64.AppImage --appdir=AppDir -e soundboard -i $$MOC_DIR/soundboard.svg -d soundboard.desktop --output appimage

    QMAKE_EXTRA_TARGETS += appimg $$PWD/linuxdeploy-x86_64.AppImage $$MOC_DIR/soundboard.svg

    QMAKE_CLEAN += $$PWD/linuxdeploy-x86_64.AppImage $$MOC_DIR/soundboard.svg
}

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /usr/bin
!isEmpty(target.path): INSTALLS += target

# Adding QxtGlobalShortcut
include(QxtGlobalShortcut/QxtGlobalShortcut.pri)