QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17
unix:LIBS += -lcurl -pthread -lrt

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

# parameters: var, prepend, append
defineReplace(prependAll) {
	for(a,$$1):result += $$2$${a}$$3
	return($$result)
}

SOURCES += \
	src/arg.cpp \
	src/clientaccess.cpp \
	src/clientapi_json.cpp \
	src/clientapi.cpp \
	src/config.cpp \
	src/datadragon.cpp \
	src/datadragonimagecache.cpp \
	src/files.cpp \
	src/json.cpp \
	src/lolautoaccept.cpp \
	src/main.cpp \
	src/mainwindow.cpp \
	src/memoryimagecache.cpp \
	src/restclient.cpp \
	src/stagesettings.cpp \
	thirdparty/Log/Log.cpp

# mainwindow.cpp

HEADERS += \
	include/arg.h \
	include/clientaccess.h \
	include/clientapi.h \
	include/config.h \
	include/datadragon.h \
	include/datadragonimagecache.h \
	include/files.h \
	include/json.h \
	include/lolautoaccept.h \
	include/mainwindow.h \
	include/memoryimagecache.h \
	include/restclient.h \
	include/stagesettings.h \
	thirdparty/Log/Log.h

# mainwindow.h

MOC_DIR = build/generated/
UI_DIR = ui/
OBJECTS_DIR = build/

FORMS += \
	ui/mainwindow.ui \
	ui/stagesettings.ui

INCLUDEPATH += $$PWD/include/ \
	$$PWD/thirdparty/Log/

#TRANSLATIONS += \
#	ts/de_DE.ts \
#	ts/en.ts

LANGUAGES = de_DE en

TRANSLATIONS = $$prependAll(LANGUAGES, $$PWD/ts/, .ts)
TRANSLATIONSQM = $$prependAll(LANGUAGES, $$PWD/ts/, .qm)

makelang.commands = lrelease $$_PRO_FILE_
updatelang.commands = lupdate $$_PRO_FILE_
QMAKE_EXTRA_TARGETS += makelang updatelang
PRE_TARGETDEPS += makelang

QMAKE_CLEAN += $$TRANSLATIONSQM

# build AppImage
unix {
	$$PWD/linuxdeploy-x86_64.AppImage.commands = wget https://github.com/linuxdeploy/linuxdeploy/releases/download/continuous/linuxdeploy-x86_64.AppImage && chmod u+x linuxdeploy-x86_64.AppImage

	$$PWD/lolautoaccept.png.commands = inkscape -z -e $$PWD/lolautoaccept.png -w 512 -h 512 $$PWD/lolautoaccept.svg

	appimg.depends = $$PWD/linuxdeploy-x86_64.AppImage $${TARGET} $$PWD/lolautoaccept.png
	appimg.commands = rm -rf AppDir ; \
		mkdir -p AppDir/ts AppDir/imgs; \
		cp $$PWD/ts/*.qm ./AppDir/ts ; \
		cp $$PWD/imgs/*.png ./AppDir/imgs; \
		./linuxdeploy-x86_64.AppImage --appdir=AppDir -e lolautoaccept -i lolautoaccept.png -d lolautoaccept.desktop --output appimage

	QMAKE_EXTRA_TARGETS += appimg $$PWD/linuxdeploy-x86_64.AppImage $$PWD/lolautoaccept.png

	QMAKE_CLEAN += $$PWD/linuxdeploy-x86_64.AppImage $$PWD/lolautoaccept.png
}

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target


# https://wiki.qt.io/Automating_generation_of_qm_files