QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17
unix:LIBS += thirdparty/XInputSimulator/build/libXInputSimulator.a -lX11 -lXtst -lXext -lxcb -lXau -pthread -lXdmcp -lrt `pkg-config opencv4 --libs`

# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

# parameters: var, prepend, append
defineReplace(prependAll) {
	for(a,$$1):result += $$2$${a}$$3
	return($$result)
}

SOURCES += \
	src/fakescreen.cpp \
	src/lolautoaccept.cpp \
	src/main.cpp \
	src/mainwindow.cpp \
	src/matcher.cpp \
	src/scaleableinputs.cpp \
	src/screen.cpp \
	src/stagesettings.cpp \
	thirdparty/Log/Log.cpp

# mainwindow.cpp

HEADERS += \
	include/fakescreen.h \
	include/lolautoaccept.h \
	include/mainwindow.h \
	include/matcher.h \
	include/scaleableinputs.h \
	include/screen.h \
	include/stagesettings.h \
	thirdparty/Log/Log.h

# mainwindow.h

MOC_DIR = build/generated/
UI_DIR = ui/
OBJECTS_DIR = build/

FORMS += \
	ui/mainwindow.ui \
	ui/stagesettings.ui

INCLUDEPATH += $$PWD/include/ \
	$$PWD/thirdparty/Log/ \
	/usr/include/opencv4/opencv \
	/usr/include/opencv4

#TRANSLATIONS += \
#	ts/de_DE.ts \
#	ts/en.ts

LANGUAGES = de_DE en

TRANSLATIONS = $$prependAll(LANGUAGES, $$PWD/ts/, .ts)
TRANSLATIONSQM = $$prependAll(LANGUAGES, $$PWD/ts/, .qm)

makelang.commands = lrelease $$_PRO_FILE_
updatelang.commands = lupdate $$_PRO_FILE_
QMAKE_EXTRA_TARGETS += makelang updatelang
PRE_TARGETDEPS += makelang

QMAKE_CLEAN += $$TRANSLATIONSQM

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target


# https://wiki.qt.io/Automating_generation_of_qm_files